DLL/ActiveForm中的线程同步处理
经常看到有网友在论坛上问DLL或ActiveForm中线程同步的问题,说线程Synchronize同步执行代码时程序死掉没反应。
如大富翁论坛网友 一少 提出问题:
Dll窗口中创建线程的问题: 为何线程结束后OnTerminate指向的过程不执行?
http://www.delphibbs.com/delphibbs/dispq.asp?LID=2801313
大富翁论坛网友 a_abj 提出问题:
我在 activexForm(写了个ocx控件)里 使用了 thread的 Synchronize方法
无法返回(到这步就停哪了),如果是exe文件(普通form)就没问题
http://www.delphibbs.com/delphibbs/dispq.asp?lid=2724466
本文试着从分析Synchronize同步执行的实现机制入手,来解决DLL/ActiveForm中线程同步的问题。
线程中进行同步时调用的Synchronize函数,仅仅是把调用调用线程、调用方法地址、异常对象封装在一个同步结构中,然后调用处理同步结构的类方法Synchronize。
procedure TThread.Synchronize(Method: TThreadMethod);
begin
FSynchronize.FThread := Self;
FSynchronize.FSynchronizeException := nil;
FSynchronize.FMethod := Method;
Synchronize(@FSynchronize);
end;
class procedure TThread.Synchronize(ASyncRec: PSynchronizeRecord);
var
SyncProc: TSyncProc;
begin
if GetCurrentThreadID = MainThreadID then // 如果是主线程,当然也就不需要同步处理了,直接执行即可
ASyncRec.FMethod
else
begin
SyncProc.Signal := CreateEvent(nil, True, False, nil); // 创建一个未命名事件,用于主线程执行同步的过程结束时通知等待线程
try
EnterCriticalSection(ThreadLock); // 进入ThreadLock关键区,用于保护对Classes单元的全局变量SyncList的访问和进行一些调用的同步
try
if SyncList = nil then
SyncList := TList.Create;
SyncProc.SyncRec := ASyncRec;
SyncList.Add(@SyncProc); // 把要同步的结构添加到列表SyncList中,等待主线程取出执行同步过程代码
SignalSyncEvent; // 调用SetEvent(SyncEvent)使同步事件SyncEvent处于信号状态,主要用在正确处理线程结束时
if Assigned(WakeMainThread) then
WakeMainThread(SyncProc.SyncRec.FThread); // 关键!Classes.WakeMainThread就是Application.WakeMainThread,通过PostMessage发个WM_NULL空消息,让主线程醒来
LeaveCriticalSection(ThreadLock); // 离开关键区,因为主线程调用的过程CheckSynchronize中会在取出SyncList列表同步结构前先进入关键区的
try
WaitForSingleObject(SyncProc.Signal, INFINITE); // 等待主线程同步调用结束通知事件
finally
EnterCriticalSection(ThreadLock);
end;
finally
LeaveCriticalSection(ThreadLock);
end;
finally
CloseHandle(SyncProc.Signal);
end;
if Assigned(ASyncRec.FSynchronizeException) then raise ASyncRec.FSynchronizeException;
end;
end;
在主线程的消息处理过程WndProc中检索到WM_NULL消息就会调用CheckSynchronize对同步列表SyncList中的同步结构进行逐个处理,直至SyncList中要同步的方法全部被同步调用完毕。而在应用程序空闲时也会调用CheckSynchronize进行同步处理。
procedure TApplication.WndProc(var Message: TMessage);
begin
try
(略)
with Message do
case Msg of
WM_NULL:
CheckSynchronize;
else
Default;
end;
except
HandleException(Self);
end;
end;
procedure TApplication.Idle(const Msg: TMsg);
begin
(略)
if (GetCurrentThreadID = MainThreadID) and CheckSynchronize then
Done := False;
if Done then WaitMessage;
end;
再看一下Delphi封装的实际线程执行体函数:
function ThreadProc(Thread: TThread): Integer;
var
FreeThread: Boolean;
begin
try
if not Thread.Terminated then
try
Thread.Execute;
except
Thread.FFatalException := AcquireExceptionObject;
end;
finally
FreeThread := Thread.FFreeOnTerminate; // 是否线程执行结束后自动释放Thread对象实例?
Result := Thread.FReturnValue;
Thread.DoTerminate; // 这里调用Synchronize(CallOnTerminate),也就是说OnTerminate事件代码实际上是在主线程中同步执行的
Thread.FFinished := True;
SignalSyncEvent; // 使同步事件SyncEvent处于信号状态,使线程Destory调用WaitFor时如果是主线程,可以进行必要的同步处理
if FreeThread then Thread.Free; // 注意:线程Destroy部分的代码是在线程执行体中执行的
EndThread(Result);
end;
end;
到这里我们基本清楚了Synchronize同步的实现机制:
线程将同步线程、方法封装成同步结构,添加到同步列表SyncList中,然后发送WM_NULL消息唤醒主线程,然后调用WaitForSingleObject挂起等待主线程处理。主线程处理WM_NULL消息或在空闲时调用CheckSynchronize,从同步列表SyncList取出同步结构,在主线程中调用执行同步方法,执行完毕通过同步结构中的未命名事件句柄通知等待线程。等待线程收到事件通知后醒来,然后继续执行。
以上是对通常的应用程序中的线程Synchronize同步实现机制的分析,而对于DLL中的线程在用Synchronize进行同步时又有它的特殊性。
DLL中的全局变量是每个DLL都复制一份的,各个DLL之间以及DLL与主程序之间不能直接进行数据共享。这也就是说主程序的SyncEvent、SyncList、ThreadLock与DLL中的SyncEvent、SyncList、ThreadLock变量是不一样的。因此在DLL中的Synchronize同步,使用到的是DLL中的SyncEvent、SyncList、ThreadLock等变量,因此,直接使用Synchronize,主程序的CheckSynchronize就无法对DLL中的线程进行同步调度执行。而DLL中的Application却从来没有运行Run进入消息循环,因此也不能调用CheckSynchronize来处理线程的同步。因此在DLL中就需要主动调用CheckSynchronize函数来对同步列表SyncList进行处理。可以在DLL中专门创建一个窗口,在窗口消息循环中处理WM_NULL消息,调用ChechSynchronize即可。
while PeekMessage(Msg, 0, 0, 0, PM_REMOVE) do
if Msg.message = WM_NULL then
CheckSynchronize
else
begin
TranslateMessage(Msg);
DispatchMessage(Msg);
end;
对ActiveForm中使用的线程调用Synchronize的情况也大体上相同,它的宿主进程是浏览器(如IE),IE一来不是Delphi编的程序,不会在主程序消息循环主调用CheckSynchronize进行同步处理的;二来即使它进行同步处理,也不是采用Delphi的同步实现方法,没有SyncList、SyncEvent、ThreadLock等变量的使用的;另外,ActiveForm由于是个OCX(实际上是种DLL),因此还有如同上述DLL中线程同步的问题,解决办法也可以和上面一样。当然,应该也可以直接在ActiveForm中添加处理WM_NULL消息的处理过程,调用CheckSynchronize进行同步处理,我没有进行试验,具体地,你可以亲自试一下。
另可参考:
Delphi 6, 7 threads synchronization in ActiveX controls
摘要: This article describes how to improve Delphi 6, 7 threads synchronization in ActiveX controls
http://dn.codegear.com/cn/article/32756
分享到:
相关推荐
通过IE执行activeform
详细介绍了在delphi2010,delphi xe3中ActiveForm的创建及发布的方法
C++ Builder 6制作ActiveForm源码
用delphi开发的聊天软件,基于Web并结合了网页中嵌入ActiveX技术,就是Delphi的ActiveForm
自己制作ActiveForm电子签名的演示文档,具体步骤察看压缩包的Word文档。 先要有工具包,包括以下几个软件: makecert.exe 制作cer格式的证书,即X.509证书,同时可以创建私钥 cert2spc.exe 将cer格式证书转换成...
delphi开发的ActiveForm 可用在Web中,实例可用,并通过测试。
ActiveForm 示例,基于Delphi的源码,通过IE执行activeform。
本文描述了最新的delphi开发工具delphiXE中开发ActiveForm的经历,与以前在delphi7中有明显的不同,希望大家能通过此文章得到启发共勉。
内容索引:Delphi源码,界面编程,ActiveForm ActiveForm 示例,基于Delphi的源码,通过IE执行activeform。
本文实例讲述了YII2.0之Activeform表单组件用法。分享给大家供大家参考,具体如下: Activeform 文本框:textInput(); 密码框:passwordInput(); 单选框:radio(),radioList(); 复选框:checkbox(),checkboxList(); ...
主要介绍了Yii2创建表单(ActiveForm)的方法,结合实例形式详细分析了Yii创建表单的详细步骤及相关函数与属性的使用技巧,需要的朋友可以参考下
php $form = ActiveForm::begin([ 'action' => ['save'], //提交地址(*可省略*) 'method'=>'post', //提交方法(*可省略默认POST*) 'id' => 'form-save', //设置ID属性 'options' => [ 'class' => 'form-...
演示如何用delphi进行activeX form编程并进行数字签名
前面我们讲述了yii2中如何使用modal以及yii2 gridview列表内更新操作如何使用modal的问题,本以为modal要告一段落可以开始新的话题了,但是实际问题往往超乎想像,这不modal弹窗提交的表单说是怎么验证的问题又出来...
gem 'activeform-rails' 请确保您正在运行兼容版本的Ruby,请参见下文。 快速示例 为了管理类别和用户,您可以创建一个像这样的对象: class Form include ActiveForm :: Form properties :name , on : :user ...
活动形式 从accepts_nested_attributes_for助手中释放您的模型。 Active Form 提供了一种面向对象的方法来通过构建表单对象来表示您的表单,而不是... ActiveForm :: Base self . main_model = :conference attribut
yii2-tabs-x 基于Krajee的的Yii Framework 2扩展选项卡小部件。 该插件包括各种CSS3样式增强功能以及对核心各种调整。 该扩展支持Bootstrap 3.x和4.x库版本。 它还可以帮助您以多种方式对齐选项卡,添加边框,...