- 浏览: 459162 次
文章分类
最新评论
-
datawarehouse:
来学习了。
什么是informatic? -
nange223:
感谢分享,学习了
一些数据库监控,优化,管理工具 -
pianxibin:
ertrth thr dj dyj
一些数据库监控,优化,管理工具 -
gekky6:
多谢分享,学习下
一些数据库监控,优化,管理工具 -
lqlein:
好好学习学习
一些数据库监控,优化,管理工具
REF CURSOR 小结
利用REF CURSOR,可以在程序间传递结果集(一个程序里打开游标变量,在另外的程序里处理数据)。
也可以利用REF CURSOR实现BULK SQL,提高SQL性能。
REF CURSOR分两种,Strong REF CURSOR 和 Weak REF CURSOR。
Strong REF CURSOR:指定retrun type,CURSOR变量的类型必须和return type一致。
DECLARE
TYPE strongcurtyp IS REF CURSOR RETURN emp%ROWTYPE;
emp_cv strongcurtyp;
Weak REF CURSOR:不指定return type,能和任何类型的CURSOR变量匹配。
DECLARE
TYPE weakcurtyp IS REF CURSOR;
weak_cv weakcurtyp;
any_cv SYS_REFCURSOR; --使用SYS_REFCURSOR可以使变量any_cv跟任何weak REF CURSOR类型匹配。
使用Strong REF CURSOR例子
CREATE OR REPLACE PACKAGE emp_data AS
TYPE empcurtyp IS REF CURSOR RETURN emp%rowtype; --定义TYPE as Strong REF CURSOR
PROCEDURE open_emp_cv(emp_cv IN OUT empcurtyp, choice INT); --根据不同的choice选择不同的CURSOR
PROCEDURE retrieve_data(choice INT); --通过调用procedure open_emp_cv,返回指定的结果集。
END emp_data;
=============================================
CREATE OR REPLACE PACKAGE BODY emp_data AS
--procedure open_emp_cv-----------------------------
PROCEDURE open_emp_cv(emp_cv IN OUT empcurtyp, choice INT) IS --emp_cv作为传入/传出的CURSOR PARAMETER
BEGIN
IF choice = 1 THEN
OPEN emp_cv FOR
SELECT * FROM emp WHERE empno < 7800;
ELSIF choice = 2 THEN
OPEN emp_cv FOR
SELECT * FROM emp WHERE SAL < 1000;
ELSIF choice = 3 THEN
OPEN emp_cv FOR
SELECT * FROM emp WHERE ename like 'J%';
END IF;
END;
--procedure retrieve_data----------------------------------
PROCEDURE retrieve_data(choice INT) IS
return_cv empcurtyp; --定义传入open_emp_cv的CURSOR变量
return_row emp%ROWTYPE;
invalid_choice EXCEPTION;
BEGIN
open_emp_cv(return_cv, choice); --调用 procedure OPEN_EMP_CV
IF choice = 1 THEN
DBMS_OUTPUT.PUT_LINE('EMPLOYEES with empno less than 7800');
ELSIF choice = 2 THEN
DBMS_OUTPUT.PUT_LINE('EMPLOYEES with salary less than 1000');
ELSIF choice = 3 THEN
DBMS_OUTPUT.PUT_LINE('EMPLOYEES with name starts with ''J''');
ELSE
RAISE invalid_choice;
END IF;
LOOP
FETCH return_cv
INTO return_row;
EXIT WHEN return_cv%NOTFOUND;
DBMS_OUTPUT.PUT_LINE(return_row.empno || '--' || return_row.ename || '--' ||
return_row.sal);
END LOOP;
EXCEPTION
WHEN invalid_choice THEN
DBMS_OUTPUT.PUT_LINE('The CHOICE should be in one of (1,2,3)!');
WHEN OTHERS THEN
DBMS_OUTPUT.PUT_LINE('Errors in procedure RETRIEVE_DATA!');
END;
END emp_data;
================================
执行:
SQL> EXEC emp_data.retrieve_data(1);
EMPLOYEES with empno less than 7800
7369--SMITH--800
7499--ALLEN--1600
7521--WARD--1250
7566--JONES--2975
7654--MARTIN--1250
7698--BLAKE--2850
7782--CLARK--2450
7788--SCOTT--3000
PL/SQL procedure successfully completed
SQL> EXEC emp_data.retrieve_data(2);
EMPLOYEES with salary less than 1000
7369--SMITH--800
7900--JAMES--950
PL/SQL procedure successfully completed
SQL> EXEC emp_data.retrieve_data(3);
EMPLOYEES with name starts with 'J'
7566--JONES--2975
7900--JAMES--950
PL/SQL procedure successfully completed
SQL> EXEC emp_data.retrieve_data(34);
The CHOICE should be in one of (1,2,3)!
PL/SQL procedure successfully completed
使用Weak REF CURSOR例子
--procedure open_cv---------------------------------------
create or replace procedure open_cv(choice IN INT,
return_cv OUT SYS_REFCURSOR) is
--参数return_cv为weak REF CURSOR,利用SYS_CURSOR来定义
begin
if choice = 1 then
open return_cv for 'select * from emp';
elsif choice = 2 then
open return_cv for 'select * from dept';
end if;
end open_cv;
--procedure retrieve_data------------------------------------
create or replace procedure retrieve_data(choice IN INT) is
emp_rec emp%rowtype;
dept_rec dept%rowtype;
return_cv SYS_REFCURSOR;
invalid_choice exception;
begin
if choice=1 then
dbms_output.put_line('employee information');
open_cv(1,return_cv); --调用procedure open_cv;
loop
fetch return_cv into emp_rec;
exit when return_cv%notfound;
dbms_output.put_line(emp_rec.empno||'-'||emp_rec.ename||'-'||emp_rec.sal);
end loop;
elsif choice=2 then
dbms_output.put_line('department information');
open_cv(2,return_cv);
loop
fetch return_cv into dept_rec;
exit when return_cv%notfound;
dbms_output.put_line(dept_rec.deptno||'-'||dept_rec.dname||'-'||dept_rec.loc);
end loop;
else
raise invalid_choice;
end if;
exception
when invalid_choice then
dbms_output.put_line('The CHOICE should be one of 1 and 2!');
when others then
dbms_output.put_line('Errors in procedure retrieve_data');
end retrieve_data;
-----------------------------------------------------------------
执行:
SQL> exec retrieve_data(1);
employee information
7369-SMITH-800
7499-ALLEN-1600
7521-WARD-1250
7566-JONES-2975
7654-MARTIN-1250
7698-BLAKE-2850
......
PL/SQL procedure successfully completed
SQL> exec retrieve_data(2);
department information
10-ACCOUNTING-NEW YORK
20-RESEARCH-DALLAS
30-SALES-CHICAGO
40-OPERATIONS-BOSTON
PL/SQL procedure successfully completed
用REF CURSOR实现BULK功能
1. To speed up INSERT, UPDATE, and DELETE statements, enclose the SQL statement within a PL/SQL FORALL statement instead of a loop construct.
2. To speed up SELECT statements, include the BULK COLLECT INTO clause in the SELECT statement instead of using INTO.
SQL> create table tab2 as select empno ID, ename NAME, sal SALARY from emp where 1=2;
Table created
-------------------------------------------------------
create or replace procedure REF_BULK is
type empcurtyp is ref cursor;
type idlist is table of emp.empno%type;
type namelist is table of emp.ename%type;
type sallist is table of emp.sal%type;
emp_cv empcurtyp;
ids idlist;
names namelist;
sals sallist;
row_cnt number;
begin
open emp_cv for
select empno, ename, sal from emp;
fetch emp_cv BULK COLLECT
INTO ids, names, sals; --BULK COLLECT INTO instead of INTO
close emp_cv;
for i in ids.first .. ids.last loop
dbms_output.put_line('id=' || ids(i) || ' name=' || names(i) ||
' salary=' || sals(i));
end loop;
forall i in ids.first .. ids.last --FORALL instead of FOR ...LOOP
insert into tab2 values (ids(i), names(i), sals(i));
commit;
select count(*) into row_cnt from tab2;
dbms_output.put_line('-----------------------------------');
dbms_output.put_line('The row number of tab2 is ' || row_cnt);
end REF_BULK;
------------------------------------------------------------
执行:
SQL> exec ref_bulk;
id=7369 name=SMITH salary=800
id=7499 name=ALLEN salary=1600
id=7521 name=WARD salary=1250
id=7566 name=JONES salary=2975
id=7654 name=MARTIN salary=1250
id=7698 name=BLAKE salary=2850
id=7782 name=CLARK salary=2450
id=7788 name=SCOTT salary=3000
id=7839 name=KING salary=5000
id=7844 name=TURNER salary=1500
id=7876 name=ADAMS salary=1100
id=7900 name=JAMES salary=950
id=7902 name=FORD salary=3000
id=7934 name=MILLER salary=1300
-----------------------------------
The row number of tab2 is 14
PL/SQL procedure successfully completed
发表评论
-
SQL数据库设计经验
2009-04-07 10:00 993SQL数据库设计经验 2009- ... -
用户sa登陆失败,原因“未与信任的SQL server连接相
2009-04-03 15:47 4127用户sa登陆失败,原因"未与信任的SQL serve ... -
oralce plsql工作中的吸取
2009-01-12 10:14 957v_prior_wip extend_wip%rowtyp ... -
oracle 远程共享
2008-12-18 10:30 951服务器想共享客户端的表 例如我自己是服务器17_test我想访 ... -
TRUNCATE TABLE----delete
2008-12-17 09:19 1920删除表中的所有行,而不记录单个行删除操作。TRUNCATE ... -
oracle 用PLSQL Developer(或者导出命令)怎么导出
2008-12-16 15:09 6386oracle 用PLSQL Developer(或者导出命令) ... -
带参数的CURSOR如何使用?
2008-12-16 10:01 4332--定义cursor cursor cuhdr(run_ ... -
树-Oracle用Start with...Connect By子句递归查询
2008-12-05 14:39 1692Start with...Connect By子句递归查询一般 ... -
怎么在oracle数据库格式的时间上加60分钟?
2008-12-03 14:42 1578这样 比如你要加上40分钟,就在日期型数据后面加上 分钟数/6 ... -
ORACLE集合常用方法
2008-11-25 10:38 2053from:http://blog.itpub.net ... -
index-by集合问题
2008-11-25 08:57 962包头: create or replace package a ... -
怎么在sqlplus调用输入参数为集合类型的包函数?---(index-by集合)
2008-11-24 16:27 1046怎么在sqlplus调用输入参数为集合类型的包函数?---(i ... -
怎么在sqlplus调用输入参数为集合类型的包函数?---(index-by集合)
2008-11-21 15:07 1125create or replace package ... -
Oracle三种集合数据类型的比较
2008-11-21 11:34 1470PL/SQL中没有数组的概念,他的集合数据类型和数组是相似的。 ... -
oracle常用命令集合(随记)
2008-11-21 11:30 1046SQL常用关键字(#:表名 ...:字段)sqlplus s ... -
FORALL与BULKCOLLECT的使用方法
2008-11-20 14:08 11821.使用FORALL比FOR效率高,因为前者只切换一次上下文, ... -
pls_integer类型
2008-11-20 13:55 2892今天在看一个触发器代码的时候碰到了一个pls_integer类 ... -
SQL Server中的分组和求和的问题
2008-11-18 16:40 3067表 物品 数量 类型 笔记本电脑 100 进货 台试机 100 ... -
MyEclipse中配置SQL server数据源
2008-11-09 15:53 38261、首先在控制面板里建立你的数据源test,必须用选用: ... -
在oracle 9i里主键的自动增长(补充)
2008-11-09 15:45 824create table ADDRESSBOOK( ...
相关推荐
本文档演示如何从 Java 存储过程将 JDBC ResultSet 作为 REF CURSOR 返回。JDBC ResultSet 是一个表示数据库的数据表,通常通过执行查询数据库的语句产生该表。REF CURSOR 是 PL/SQL 中相应的类型。Java 存储过程的...
主要给大家介绍了关于oracle如何合并多个sys_refcursor的相关资料,以及在文末跟大家分享了sys_refcursor 和 cursor 优缺点的比较,文中通过示例代码介绍的非常详细,需要的朋友可以参考借鉴,下面来一起学习学习吧
1.Oracle基本数据类型存储格式浅析 2.一次SQL Tuning引出来的not...3.REF CURSOR 小结 4.日期转换函数的格式参数大小写规则 5.Oracle数据库字符集问题解析 6.关于Oracle10g跨平台传输表空间 7.oracle常用命令(学习笔记)
PLSQL中显示Cursor、隐示Cursor、动态Ref_Cursor区别(有分支图解)
Extref
out和ref的区别 out和ref的区别
var ref = require('ref') var StructType = require('ref-struct') // define the time types var time_t = ref.types.long var suseconds_t = ref.types.long // define the "timeval" struct type var timeval ...
关于一个Ref和Out参数的例子,更易理解Ref和Out参数
ABB馈线保护测控装置REF611产品指南pdf,ABB馈线保护测控装置REF611产品指南:REF611 馈线保护测控装置,专为公用和工业配电系统的保护、控制、测量和监视而设计,可用于辐射型、环型或网络型配电网络,支持带有分布式...
回页首java.lang.ref 包的介绍我们可以先来看一下 java.lang.ref 这个包的结构,如图 1 所示图 1. java.lang.ref 包结
正确理解C#中的ref关键字,有助于编程人员对ref的理解
本手册详细介绍了馈线保护继电器REF_615的原理及操作。
REF19XSERIES.pdf
The REF30xx is a precision, low power, low voltage dropout voltage reference family available in a tiny SOT23-3.
全面详细的讲解REF_ET软件的使用,并对各种方法深层分析
用于编辑和读取ABB REF542 4E04d的软件 REF542PLUS 为1款微机保护装置
REF3212数据手册.pdf
GLOBK_Ref.pdf
C_中out和ref的区别,这是基础的C#知识点!