package {
import flash.display.*;
import flash.events.*;
import flash.geom.*;
import flash.text.*;
import org.papervision3d.scenes.*;
import org.papervision3d.objects.*;
import org.papervision3d.cameras.*;
import org.papervision3d.materials.*;
[SWF(width="400", height="400", backgroundColor="#000000", frameRate="30")]
// BitmapMaterial と MovieMaterial (テキスト表示) のサンプル
public class MaterialSample extends Sprite {
private var container : Sprite;
private var scene : Scene3D;
private var camera : Camera3D;
private var rootNode : DisplayObject3D;
private var obj:Array = new Array();
// 3Dオブジェクト踊らせ用パラメータ
private var valx : Number = 0;
private var valy : Number = 0;
// Bitmap
private var bitmapdata:BitmapData;
// Text
private var text:TextField;
private var material:MovieMaterial
public function MaterialSample():void {
// 画面いっぱいに表示(縦横比無視)したいときはコレを使う
// stage.scaleMode = StageScaleMode.EXACT_FIT;
// リサイズに対応(swfをブラウザで直接ひらいているときとか)
stage.addEventListener(Event.RESIZE, onStageResize);
// 定期的にイベント発生
addEventListener(Event.ENTER_FRAME, myLoopEvent);
// マウスクリックでイベント発生
stage.addEventListener(MouseEvent.CLICK, myClick);
// 表示用の Sprite オブジェクトを生成
container = new Sprite();
container.x = 400 / 2; // at center : swf width = 400
container.y = 400 / 2; // at center : swf height = 400
addChild(container);
// シーンオブジェクトを作る
scene = new Scene3D(container);
// カメラオブジェクトを作る
camera = new Camera3D();
camera.z = -200;
camera.focus = 500;
camera.zoom = 1;
// ルートノードを作る
rootNode = new DisplayObject3D();
scene.addChild(rootNode);
// いろんな3Dオブジェクトを作ってみて、配列に入れておく
obj.push(createWireframePlane());
obj.push(createBitmapPlane());
obj.push(createTextPlane());
obj.push(createTextCube());
// 3Dオブジェクトをルートノードに追加
for(var i:int; i<obj.length; i++){
rootNode.addChild(obj[i]);
}
}
private function createWireframePlane():DisplayObject3D {
var material:WireframeMaterial = new WireframeMaterial();
material.oneSide = false;
material.lineColor = 0x00FF00;
material.lineAlpha = 1;
var planeSize:int = 200;
var segment:int = 2;
var plane:Plane = new Plane(
material, planeSize, planeSize, segment, segment);
plane.x = 0;
plane.y = 180;
plane.z = 0;
return plane;
}
private function createBitmapPlane():DisplayObject3D {
var bd:BitmapData = new BitmapData(100, 100, false);
this.bitmapdata = bd; // using this
var material:BitmapMaterial = new BitmapMaterial(bd);
material.oneSide = false;
material.lineColor = 0x00FF00;
material.lineAlpha = 1;
var planeSize:int = 200;
var segment:int = 2;
var plane:Plane = new Plane(
material, planeSize, planeSize, segment, segment);
plane.x = -180;
plane.y = 0;
plane.z = 0;
return plane;
}
private function createTextPlane():DisplayObject3D {
var asset:MovieClip = createMovieClip();
var transparent:Boolean = true;
var initObject:Object = {animated:true, doubleSided:true};
var material:MovieMaterial = new MovieMaterial(asset, transparent, initObject);
this.material = material; // using this
var planeSize:int = 200;
var segment:int = 2;
var plane:Plane = new Plane(
material, planeSize, planeSize, segment, segment);
plane.x = 180;
plane.y = 0;
plane.z = 0;
return plane;
}
private function createTextCube():DisplayObject3D {
var planeSize:int = 200;
var segment:int = 2;
// using this
var cube:Cube = new Cube(
this.material, planeSize, planeSize, planeSize, segment, segment, segment);
cube.x = 0;
cube.y = 0;
cube.z = 0;
return cube;
}
private function createMovieClip():MovieClip {
var mc:MovieClip = new MovieClip();
var text:TextField = createTextField();
text.text = getPropertiesString(mc);
mc.addChild(text);
this.text = text; // using this
return mc;
}
private static function createTextField():TextField{
// 表示メッセージのスタイル
var format:TextFormat = new TextFormat();
format.bold = false;
format.italic = false;
format.size = 10;
format.underline = false;
format.font = "_等幅";
// 表示メッセージ
var text:TextField = new TextField();
text.autoSize = TextFieldAutoSize.LEFT;
text.selectable = false;
text.setTextFormat(format);
text.background = true;
text.backgroundColor = 0x000000;
text.border = false;
text.borderColor = 0xFFFFFF;
text.textColor = 0xFFFFFF;
return text;
}
// 最初だけこんなの表示してみる
private static function getPropertiesString(mc:MovieClip):String {
var str:String = ""
+ "currentFrame: " + mc.currentFrame + "\n"
+ "currentLabel: " + mc.currentLabel + "\n"
+ "currentScene: " + mc.currentScene + "\n"
+ "framesLoaded: " + mc.framesLoaded + "\n"
+ "totalFrames: " + mc.totalFrames + "\n"
+ "trackAsMenu: " + mc.trackAsMenu + "\n";
return str;
}
private function myClick(event:MouseEvent):void {
// update Bitmap
// Math.random: (0 <= n < 1)
var x:int = (int)(Math.random() * 100);
var y:int = (int)(Math.random() * 100);
// bitmapdata.setPixel(x, y, 0xFF0000);
var rect:Rectangle = new Rectangle(x, y, 20, 20);
bitmapdata.fillRect(rect, 0xFF0000);
// update Text
text.border = !text.border; // ワクを付けたり消したり
text.background = !text.background; // 背景を付けたり消したり
text.text = "マウスを\nクリックした位置:\nLocation(" + container.mouseX + "," + container.mouseY + ")";
material.updateBitmap(); // 更新を通知
//scene.renderCamera(camera);
}
private function myLoopEvent(event:Event):void {
valx += container.mouseX / 50;
valy += container.mouseY / 50;
for(var i:int; i<obj.length; i++){
obj[i].rotationY = valx;
obj[i].rotationX = valy;
}
scene.renderCamera(camera);
}
private function onStageResize(event:Event):void {
container.x = stage.stageWidth / 2;
container.y = stage.stageHeight / 2;
}
}
}
分享到:
相关推荐
Papervision3D is a powerful real-time 3D engine for Flash. Papervision3D can take externally created 3D models and render them as Flash content, without requiring end-users to download or install an ...
Papervision3D 教程,pv3d,pv3d+Flex,pv3d中文帮助
Papervision3D_2.0.869.swc
Papervision3D是一个基于ActionScript的开源项目,目的在于实现更加炫丽美观、功能强大的Flash 3D Web应用程序。尤其是去年ActionScript 3发布了之后,ActionScript的效率得到了大幅度提升,基于此的Papervision3D...
使用papervision3d引擎做的7个实例源码
例子来自于Flash3D研究所,超简易Papervision3D基础 Main.cs 小球加外部贴图 Main2.cs 物体的各种移动 (讲解移动/旋转/放大物体的方法) Main3.cs导入外部模型 (讲解如何从外部软件导入collada文件) Main4.cs pv...
Papervision3D_2.1.932.swcPapervision3D_2.1.932.swcPapervision3D_2.1.932.swc
Papervision3D的api,这个帮助文档介绍各种包的使用,有利于快速学习3D
《Papervision3D+Essentials》中文翻译
Papervision3D Essentials 中文版 翻译 第一章 docx格式
整理了Papervision3d的各方面资料,并且提供一个全景代码案例!
希望对学习PV3D引擎的人提供点帮助。这是一pv3D的api电子书
Papervision3D Essentials (PV3D)的中文版电子书及 书中实例源码下载 PV3D FLEX 三维渲染必备开源包
一个不错的Flash 3D引擎Papervisio3D,让你的flash从2D转化3D不再是难事.最新版本as3
papervisiion3d sdk,开发环境myeclipse+flex+pv3d
papervision3d 精髓,入门者必备,最新版本
博文链接:https://ioryioryzhan.iteye.com/blog/206368
actionscript 3d 引擎papervision3d的api,chm格式,方便大家使用papervision3d开发3d是查阅
Papervision3D.doc Papervision3D入门 Collada模型文件
flashplayer 11 播放器 Papervision3D -帮助文档 Papervision3D_2[1].1.920.swc Papervision3D源码例子 帮助文档 需要解锁 ,源码例子拷贝到新建工程的AS 类中,修改名称和类名就可以运行了。