flex管理声音文件的办法

这是一整个完整的类，仅供学习使用！希望大家不要追溯版权问题，这个类使用了一个常量类来完成功能，常量类我就不放出了，相信看懂了，应该可以自己写出来。

public class SoundManager
	{
		/**
		 * 默认声音大小
		 */		
		public var defaultVolume:Number=1.0;
		
		private var activeSound:Dictionary;
		
		private var _soundOn:Boolean=true;//是否关闭声音,游戏音效
		private var _bgSoundOn:Boolean=true;//是否关闭背景音乐
				
		private static var _instance:SoundManager=null;
		
		
		public function SoundManager()
		{
			activeSound = new Dictionary();
		}
		
		
		/**
		 * 设置全局声音的大小
		 * @param volume 声音音量
		 * 
		 */		
		public function setGlobalVolume(volume:Number):void
		{
			SoundMixer.soundTransform = new SoundTransform(volume);			
		}
		/**
		 * 设置声音的大小
		 *  
		 * @param name	名称
		 * @param volume	声音
		 */	
		public function setVolume(name:String, volume:Number):void
		{
			var sc:SoundChannel = getActiveChannel(name);
			if (sc)
				sc.soundTransform = new SoundTransform(volume);			
		}
		/**
		 *取声音通道 
		 * @param name
		 * @return 
		 * 
		 */		
		public function getActiveChannel(name:String):SoundChannel
		{
			return activeSound[name];
		}
		/**
		* 设置声音位置
		* 
		* @param name	名称
		* @param pan	声音位置，范围由-1到1		
		*/
		public function setPan(name:String, pan:Number):void
		{
			var sc:SoundChannel = getActiveChannel(name);
			if (sc)
			{				
				sc.soundTransform = new SoundTransform(sc.soundTransform.volume,pan);
			}
		}
		
		/**
		 * 声音是否正在播放
		 *  
		 * @param name	名称
		 * 
		 */	
		public function isPlaying(name:String):Boolean
		{
			return activeSound[name]!=null;
		}
		
		/**
		 * 停止播放
		 *  
		 * @param name	名称
		 */	
		public function stop(name:String):void
		{
			var sc:SoundChannel = activeSound[name];
			delete activeSound[name];
			
			if (sc)
			{
				sc.stop();				
			}
		}
		/**
		 * 停止播放所有正在播放的音乐 
		 * 
		 */		
		public function stopAll():void
		{
			SoundMixer.stopAll();
		}
		/**
		 * 播放
		 *  
		 * @param name	名称
		 * @param loop	循环次数，-1为无限循环
		 * @param volume	声音		
		 */		
		public function play(name:String,startTime:Number=0, loop:int=1, volume:Number=-1,panning:Number=0):void
		{			
			try
			{
				var ref:Class;
				if(ApplicationDomain.currentDomain.hasDefinition(name))
					ref = ApplicationDomain.currentDomain.getDefinition(name) as Class;
				else
					return;
				var _sound:Sound=new ref() as Sound;
				var channel:SoundChannel = _sound.play(startTime, (loop != -1)?loop:int.MAX_VALUE);
				
				if (channel)
				{
					if (loop != 0 && loop != -1)
						channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteListener);
					
					activeSound[name] = channel;					
					channel.soundTransform = new SoundTransform((volume != -1) ? volume : defaultVolume,panning);	
					
					if(!_soundOn&&name!=SoundsConst.BATTLE_SOUND&&name!=SoundsConst.BG1_SOUND)//游戏音效关闭
					{
						channel.soundTransform = new SoundTransform(0);	
					}
					
					if(!_bgSoundOn&&(name==SoundsConst.BATTLE_SOUND||name==SoundsConst.BG1_SOUND))//背景音乐关闭
					{
						channel.soundTransform = new SoundTransform(0);	
					}
				}
			}
			catch(e:Error)
			{
			}	
		}
		private function soundCompleteListener(evt:Event):void
		{
			evt.currentTarget.removeEventListener(Event.SOUND_COMPLETE, soundCompleteListener);
			
			for (var key:* in activeSound)
			{
				if (activeSound[key] == evt.currentTarget)
				{
					delete activeSound[key];
					return;
				}	
			}
			
		}
		/**
		 *取SoundManager对象 
		 * @return 
		 * 
		 */		
		public static function getInstance():SoundManager
		{
			if(_instance==null)
				_instance=new SoundManager();
			
			return _instance;
		}
		/**
		 *是否关闭音乐 
		 * @return 
		 * 
		 */
		public function get soundOn():Boolean
		{
			return _soundOn;
		}		 
		/**
		 * 是否关闭游戏音效
		 * @param value
		 * 
		 */		
		public function set soundOn(value:Boolean):void
		{
			if(_soundOn!=value)
			{
				_soundOn = value;
				
				for (var key:* in activeSound)
				{
					if (key != SoundsConst.BG1_SOUND&&key != SoundsConst.BATTLE_SOUND)
					{
						var _sc:SoundChannel=activeSound[key];
						
						if (_sc)
						{
							if(!_soundOn)
								_sc.soundTransform = new SoundTransform(0);	
							else
								_sc.soundTransform = new SoundTransform(1);	
						}
					}	
				}				
			}			
		}

		/**
		 *是否关闭背景音乐 
		 * @return 
		 * 
		 */		
		public function get bgSoundOn():Boolean
		{
			return _bgSoundOn;
		}		
		/**
		 * 是否关闭背景音乐 
		 * @param value
		 * 
		 */		
		public function set bgSoundOn(value:Boolean):void
		{
			if(_bgSoundOn!=value)
			{
				_bgSoundOn = value;
			
				if(!_bgSoundOn)
				{
					setVolume(SoundsConst.BG1_SOUND,0);
					setVolume(SoundsConst.BATTLE_SOUND,0);
				}
				else
				{
					setVolume(SoundsConst.BG1_SOUND,1);
					setVolume(SoundsConst.BATTLE_SOUND,1);
				}
			}
		}