Flex AIR(WindowedApplication)与Java的socket通讯例子。

Socket服务器：

import java.io.BufferedReader;
import java.io.BufferedWriter;
import java.io.IOException;
import java.io.InputStreamReader;
import java.io.OutputStreamWriter;
import java.net.ServerSocket;
import java.net.Socket;

class SimpleServer {
	private static SimpleServer simpleServer;
	private ServerSocket server;
	private Socket client;
	private BufferedReader reader;
	private BufferedWriter writer;

	public static void main(String[] args) {
		int port = 9999;

		try {
			port = Integer.parseInt(args[0]);
		} catch (ArrayIndexOutOfBoundsException e) {
			// Catch exception and keep going.
		}

		simpleServer = new SimpleServer(port);
	}

	private SimpleServer(int port) {
		System.out.println(">> Starting SimpleServer");
		try {
			server = new ServerSocket(port);
			client = server.accept();
			reader = new BufferedReader(new InputStreamReader(client
					.getInputStream(), "UTF-8"));
			writer = new BufferedWriter(new OutputStreamWriter(client
					.getOutputStream(), "UTF-8"));

			writer.write("输入\"EXIT\"退出.\r");
			System.out.println("输入\"EXIT\"退出.");
			boolean done = false;
			while (!done) {
				String str = reader.readLine();
				if (str == null) {
					done = true;
				} else {
					if (str.trim().equals("EXIT")) {
						done = true;
					} else {
						str = "我接收到(server):" + str.trim() + "\r";
						out(str);
					}
				}

			}
			client.close();
		} catch (Exception e) {
			e.printStackTrace();
		}
	}

	private void out(String str) {
		try {
			writer.write(str);
			writer.flush();
			System.out.println(str);
		} catch (Exception e) {
			e.printStackTrace();
		}
	}
}

用法：
1.代码另存为SimpleServer.java
2.javac SimpleServer.java
3.java SimpleServer

Socket客户端:

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml"
						layout="vertical"
						applicationComplete="appComp()">
	<mx:Script>
		<![CDATA[
			private var socketServer:Socket;
			[Bindable]
			private var response:String="";

			private function appComp():void
			{
				//连接服务器
				var server:String="localhost";
				var port:int=9999;

				socketServer=new Socket(server, port);
				//配置事件监听器
				configListeners();
			}

			/**
			 * 配置事件监听器
			 */
			private function configListeners():void
			{
				//socket关闭事件
				socketServer.addEventListener(Event.CLOSE, closeHandler);
				//socket连接成功事件
				socketServer.addEventListener(Event.CONNECT, connectHandler);
				//socket连接不成功出的IO错误事件
				socketServer.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
				//访问权限出错事件
				socketServer.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
				//
				socketServer.addEventListener(ProgressEvent.SOCKET_DATA, socketDataHandler);

			}

			//socket写字节函数
			private function writeln(str:String):void
			{
				str+="\n";
				try
				{
					socketServer.writeUTFBytes(str);
				}
				catch (e:IOError)
				{
					trace(e);
				}
			}
			
			//发送信息函数
			private function sendRequest():void
			{
				trace("sendRequest");
				response+=inTxt.text + "\n";
				writeln(inTxt.text);
				socketServer.flush();
				inTxt.text = "";
			}
			
			//读入响应信息函数
			private function readResponse():void
			{
				var str:String=socketServer.readUTFBytes(socketServer.bytesAvailable);
				response+=str;
			}
			
			/**
			 * 关闭处理函数
			 */
			private function closeHandler(event:Event):void
			{
				trace("closeHandler: " + event);
				trace(response.toString());
			}
			
			/**
			 * 连接成功处理函数
			 */
			private function connectHandler(event:Event):void
			{
				trace("connectHandler: " + event);
				response+="已连接"
			}
			
			/**
			 * socket的IO错误处理函数
			 */
			private function ioErrorHandler(event:IOErrorEvent):void
			{
				trace("ioErrorHandler: " + event);
			}
			
			/**
			 * 安全错误处理函数
			 */
			private function securityErrorHandler(event:SecurityErrorEvent):void
			{
				trace("securityErrorHandler: " + event);
			}
			
			/**
			 * socket处理函数
			 */
			private function socketDataHandler(event:ProgressEvent):void
			{
				trace("socketDataHandler: " + event);
				readResponse();
			}
			
			/**
			 * 发送按钮点击事件处理函数
			 */
			private function onClick(evt:Event):void
			{
				sendRequest();
			}
		]]>
	</mx:Script>

	<mx:TextArea text="{response}"
				 id="outTxt"
				 height="126"
				 width="283"
				 fontSize="12"/>
	<mx:HBox verticalAlign="bottom"
			 width="282"
			 height="40">
		<mx:TextArea id="inTxt"
					 width="100%"
					 height="100%"
					 fontSize="12"/>
		<mx:Button label="发送"
				   fontSize="12"
				   click="onClick(event)"/>
	</mx:HBox>
</mx:WindowedApplication>

评论

1 楼 zwljava 2012-07-28  

不错，整合java和air比较方便的办法。