AS3 E4X - 相关类别与物件建立

转自http://ticore.blogspot.com/2007/06/as3-e4x.html

ActionScript 3.0 中与 E4X (ECMAScript for XML) 相关的内建类别有：
XML、XMLList、Namespace、QName
以及两個 global function：
XML、XMLList

建立 AS3 XML 物件

直接宣告 XML 物件：
var xml:XML = <xml></xml>;
trace(xml.toXMLString());

建构式解析字串建立：
var xml:XML = new XML("<xml></xml>");
trace("xml : " + xml.toXMLString());

全域函式解析字串建立：
var xml:XML = XML("<xml></xml>");
trace("xml : " + xml.toXMLString());

由全域函式传入其它 XML 得到參考：
var xml1:XML = <xml></xml>;
var xml2:XML = XML(xml1);
xml1.* += <node />;
trace("xml1 : " + xml1.toXMLString());
trace("xml2 : " + xml2.toXMLString());

从其它 XML 物件复制建立：
var xml1:XML = <xml></xml>;
var xml2:XML = new XML(xml1);
xml1.* += <node />;
trace("xml1 : " + xml1.toXMLString());
trace("xml2 : " + xml2.toXMLString());
var xml1:XML = <xml></xml>;
var xml2:XML = xml1.copy();
xml1.* += <node />;
trace("xml1 : " + xml1.toXMLString());
trace("xml2 : " + xml2.toXMLString());

由 XML Template 建立：
var nodeName:String = "xml";
var attrName:String = "attr";
var attrValue:String = "Attribute";
var txt:String = "Text Node";
var xml:XML = <{nodeName} {attrName}={attrValue}>{txt}</{nodeName}>;
trace(xml.toXMLString());

建立 AS3 XMLList 物件
由全域函式解析字串建立：
var xmlList:XMLList = XMLList("<xml>text1</xml><xml>text2</xml>");
trace(xmlList[0]);
trace(xmlList[1]);
trace(xmlList.toXMLString());

由全域函式传入其它 XMLList 得到參考：
var xml:XML =
<xml>
<node/>
<node/>
<node/>
</xml>;
var xmlList:XMLList = XMLList(xml.node);
xml.node[0].* = "text";
trace(xml.*.toXMLString());
trace(xmlList.toXMLString());

使用空白建构式建立：
var xmlList:XMLList = new XMLList();
xmlList[0] = <xml />;
xmlList[1] = "text";
xmlList[2] = <node />;
trace(xmlList.toXMLString());

建构式传入其它 XMLList 参数得到参考：
var xml:XML =
<xml>
<node/>
<node/>
<node/>
</xml>;
var xmlList:XMLList = new XMLList(xml.node);
xml.node[0].* = "text";
trace(xml.*.toXMLString());
trace(xmlList.toXMLString());

建构式解析字串建立：
var xmlList:XMLList = new XMLList("<xml>text1</xml><xml>text2</xml>");
trace(xmlList[0]);
trace(xmlList[1]);
trace(xmlList.toXMLString());

由 XML 物件筛选得到参考： var xml:XML =
<xml>
<node/>
<node/>
<node/>
</xml>;
var xmlList:XMLList = xml.node;
trace(xmlList.toXMLString());