1 RECORD、VARRAY、TABLE的详解
1.1 RECORD
定义记录数据类型。它类似于C语言中的结构数据类型(STRUCTURE),PL/SQL提供了将几个相关的、分离的、基本数据类型的变量组成一个整体的方法,即RECORD复合数据类型。在使用记录数据类型变量时,需要在声明部分先定义记录的组成、记录的变量,然后在执行部分引用该记录变量本身或其中的成员。
定义记录数据类型的语法如下:
TYPE RECORD_NAME IS RECORD(
V1 DATA_TYPE1 [NOT NULL][:=DEFAULT_VALUE],
V2 DATA_TYPE2 [NOT NULL][:=DEFAULT_VALUE],
VN DATA_TYPEN [NOT NULL][:=DEFAULT_VALUE]);
1.2 VARRAY
数组是具有相同数据类型的一组成员的集合。每个成员都有一个唯一的下标,它取决于成员在数组中的位置。在PL/SQL中,数组数据类型是VARRAY(variable array,即可变数组)。
定义VARRAY数据类型的语法如下:
TYPE VARRAY_NAMEIS VARRAY(SIZE) OF ELEMENT_TYPE [NOT NULL];
其中,varray_name是VARRAY数据类型的名称,size是正整数,表示可以容纳的成员的最大数量,每个成员的数据类型是element_typeo默认时,成员可以取空值,否则需要使用NOT NULL加以限制。
1.3 TABLE
定义记录表(或索引表)数据类型。它与记录类型相似,但它是对记录类型的扩展。它可以处理多行记录,类似于C语言中的二维数组,使得可以在PL/SQL中模仿数据库中的表。
定义记录表类型的语法如下:
TYPE TABLE NAME IS TABLE OF ELEMENT_TYPE [NOT NULL]
INDEX BY [BINARY_INTEGER|PLS_INTEGER|VARRAY2];
关键字INDEX BY表示创建一个主键索引,以便引用记录表变量中的特定行。
BINARY_INTEGER的说明
如语句:TYPE NUMBERS IS TABLE OF NUMBER INDEX BY BINARY_INTEGER;其作用是,加了”INDEX BYBINARY_INTEGER ”后,NUMBERS类型的下标就是自增长,NUMBERS类型在插入元素时,不需要初始化,不需要每次EXTEND增加一个空间。
而如果没有这句话“INDEXBY BINARY_INTEGER”,那就得要显示对初始化,且每插入一个元素到NUMBERS类型的TABLE中时,都需要先EXTEND。
2 举例
2.1 创建表结构以及数据准备
--组织机构结构表
CREATE TABLE SF_ORG
(
ORG_ID INT NOT NULL, --组织机构主键ID
ORG_NAME VARCHAR2(50),--组织机构名称
PARENT_ID INT--组织机构的父级
)
--一级组织机构
INSERT INTO SF_ORG(ORG_ID, ORG_NAME, PARENT_ID) VALUES(1, '一级部门1',0);
--二级部门
INSERT INTO SF_ORG(ORG_ID, ORG_NAME, PARENT_ID) VALUES(2, '二级部门2',1);
INSERT INTO SF_ORG(ORG_ID, ORG_NAME, PARENT_ID) VALUES(3, '二级部门3',1);
INSERT INTO SF_ORG(ORG_ID, ORG_NAME, PARENT_ID) VALUES(4, '二级部门4',1);
2.2 RECORD的使用举例
先定义一个只与SF_ORG表中某几个列的数据类型相同的记录数据类型TYPE_ORG_RECORD,然后声明一个该数据类型的记录变量V_ORG_RECORD,最后用替换变量&ORG_ID接受输入的雇员编码,查询并显示该雇员的这几列中的信息。注意,在使用RECORD数据类型的变量时要用“.”运算符指定记录变量名限定词。
一个记录类型的变量只能保存从数据库中查询出的一行记录,如果查询出了多行记录,就会出现错误。
DECLARE
TYPE type_org_record IS RECORD(
v_org_name sf_org.org_name%TYPE,
v_parent_id sf_org.parent_id%TYPE);
v_org_record type_org_record;
BEGIN
SELECT org_name,
parent_id
INTO v_org_record
FROM sf_org so
WHERE so.org_id = &org_id;
dbms_output.put_line('部门名称:' || v_org_record.v_org_name);
dbms_output.put_line('上级部门编码:' || TO_CHAR(v_org_record.v_parent_id));
END;
2.3 VARRAY的使用举例
先定义一个能保存5个VARCHAR2(25)数据类型的成员的VARRAY数据类型ORG_VARRAY_TYPE,然后声明一个该数据类型的VARRAY变量V_ORG_VARRAY,最后用与ORG_VARRAY_TYPE数据类型同名的构造函数语法给V_ORG_VARRAY变量赋予初值并显示赋值结果。
注意,在引用数组中的成员时.需要在一对括号中使用顺序下标,下标从1开始而不是从0开始。
DECLARE
TYPE org_varray_type IS VARRAY(5) OF VARCHAR2(25);
v_org_varray org_varray_type;
BEGIN
v_org_varray := org_varray_type('1', '2', '3', '4', '5');
dbms_output.put_line('输出1:' || v_org_varray(1) || '、' || v_org_varray(2) || '、' || v_org_varray(3) || '、' || v_org_varray(4));
/*
FOR i IN v_org_varray.first .. v_org_varray.last LOOP
dbms_output.put_line('输出' || i || ':' || v_org_varray(i));
END LOOP;
*/
-- 修改单个值
dbms_output.put_line('输出2:' || v_org_varray(5));
v_org_varray(5) := '5001';
dbms_output.put_line('输出3:' || v_org_varray(5));
END;
2.4 TABLE使用举例
2.4.1 存储单列多行
这个和VARRAY类似。但是赋值方式稍微有点不同,不能使用同名的构造函数进行赋值。具体的如下:
-- 标号数组
DECLARE
TYPE org_table_type IS TABLE OF VARCHAR2(25) INDEX BY BINARY_INTEGER; -- 标号数组,不需要动态申请
v_org_table org_table_type;
BEGIN
-- 标号数组声明不能整体赋初值,会报错
--V_ORG_TABLE := ORG_TABLE_TYPE( '1', '2', '3', '4', '5' );
v_org_table(1) := '1';
v_org_table(2) := '2';
v_org_table(3) := '3';
v_org_table(4) := '4';
v_org_table(5) := '5';
dbms_output.put_line('输出1:' || v_org_table(1) || '、' || v_org_table(2) || '、' || v_org_table(3) || '、' || v_org_table(4));
dbms_output.put_line('输出2:' || v_org_table(5));
/* for i in v_org_table.first .. v_org_table.last loop
dbms_output.put_line('输出'|| i ||':' || v_org_table(i));
end loop;*/
END;
-- 非标号数组
DECLARE
TYPE org_table_type IS TABLE OF VARCHAR2(25); -- 非标号,需要动态初始化,动态extend
v_org_table org_table_type;
BEGIN
-- 报错,非标号需要动态初始化,动态extend , 否则会报错
-- v_org_table(1) := '1';
-- 初始化1, 声明时赋初值, 可以整体赋值,不需要动态extend
--V_ORG_TABLE := ORG_TABLE_TYPE( '1', '2', '3', '4', '5' );
-- 初始化2
v_org_table := org_table_type();
v_org_table.extend;
v_org_table(1) := '1';
v_org_table.extend;
v_org_table(2) := '2';
v_org_table.extend;
v_org_table(3) := '3';
v_org_table.extend;
v_org_table(4) := '4';
v_org_table.extend;
v_org_table(5) := '5';
dbms_output.put_line('输出1:' || v_org_table(1) || '、' || v_org_table(2) || '、' || v_org_table(3) || '、' || v_org_table(4));
dbms_output.put_line('输出2:' || v_org_table(5));
/* for i in v_org_table.first .. v_org_table.last loop
dbms_output.put_line('输出'|| i ||':' || v_org_table(i));
end loop;*/
END;
2.4.2 存储多列多行和ROWTYPE结合使用
采用bulkcollect可以将查询结果一次性地加载到collections中。而不是通过cursor一条一条地处理。
DECLARE
TYPE t_type IS TABLE OF sf_org%ROWTYPE;
v_type t_type;
BEGIN
SELECT org_id,
org_name,
parent_id BULK COLLECT
INTO v_type
FROM sf_org
WHERE sf_org.org_id <= 3;
FOR v_index IN v_type.first .. v_type.last LOOP
dbms_output.put_line(v_type(v_index).c1 || ' ' || v_type(v_index).c2);
END LOOP;
END;
2.4.3 存储多列多行和RECORD结合使用
采用bulkcollect可以将查询结果一次性地加载到collections中。而不是通过cursor一条一条地处理。
DECLARE
TYPE test_emp IS RECORD(
c1 sf_org.org_name%TYPE,
c2 sf_org.parent_id%TYPE);
TYPE t_type IS TABLE OF test_emp;
v_type t_type;
BEGIN
SELECT org_name,
parent_id BULK COLLECT
INTO v_type
FROM sf_org
WHERE sf_org.org_id <= 3;
FOR v_index IN v_type.first .. v_type.last LOOP
dbms_output.put_line(v_type(v_index).c1 || ' ' || v_type(v_index).c2);
END LOOP;
END;
3 问题
VARRAY和TABLE集合不能直接对其进行查询。只能对其进行遍历。
分享到:
相关推荐
主要介绍了oracle中变长数组varray,嵌套表,集合使用方法,需要的朋友可以参考下
本文主要介绍的是关于sql Oracle匿名TABLE/VARRAY类型的相关内容,在Oracle中,我有时会创建一些这样的结构 SELECT * FROM TABLE(STRINGS('a', 'b', 'c')) SELECT * FROM TABLE(NUMBERS(1, 2, 3)) 显然,我可以为...
oracle更加支持集合的应用,详细讲述了三种集合的类型:嵌套表、关联数组、varray集合。以丰富实用的例子进行了具体分析。
代码段如下: 代码如下: declare type t_indexby is table of number index by binary_integer; type t_nesteed is table of number; type t_varray is varray(10) of number; v_indexby t_indexby; v_nested t_...
联合数组详解: 什么是数组?数组有什么特点 数据是线性存放的,在内存中地址是连续的 可以用索引来访问 定义联合数组? 联合数组不需要定义长度,他能容纳的元素最大数量是-214483647-到214483647 联合数组的索引...
NULL 博文链接:https://rooi.iteye.com/blog/1337383
全面用例详解PL集中的开发细节与概念,把集合应用到官方指定的位置
1. Create table命令 用于创建表。在创建表时,经常会创建该表的主键、外键、唯一约束、Check约束等 语法结构 create table 表名( [字段名] [类型] [约束] ……….. CONSTRAINT fk_column FOREIGN KEY(column1...
使用复合数据类型 8.1 PL/SQL记录 8.1.1 定义PL/SQL记录 8.1.2 使用PL/SQL记录 8.2 PL/SQL集合 8.2.1 索引表 8.2.2 嵌套表 8.2.3 变长数组(VARRAY) 8.2.4 PL/SQL记录表...
2) 组合型:RECORD(常用)、TABLE(常用)、VARRAY(较少用) 3) 参考型:REF CURSOR(游标)、REF object_type 4) LOB(Large Object) 2. %TYPE [变量名] [表名.字段名] [%TYPE] 表示变量具有与数据库的表中某一...
·定义和部署varray 、嵌套表和联合数组数据类型; ·处理外部例程、对象类型、大对象和安全文件; ·使用DBMS_ALERT 和DBMS_PIPE 在并行会话间通信; ·通过Oracle Net Services 和PL/SQL 包装器调用外部...
·定义和部署varray 、嵌套表和联合数组数据类型; ·处理外部例程、对象类型、大对象和安全文件; ·使用DBMS_ALERT 和DBMS_PIPE 在并行会话间通信; ·通过Oracle Net Services 和PL/SQL 包装器调用外部...
Oracle游标使用方法及语法大全.doc
Preset code formatting rule added for Oracle VARRAY. Preset code formatting rule added for DEFAULT VALUES in INSERT/UPDATE statements in Transact-SQL. Database name and schema name completion is now...
Delphi WebBrowser 将一段HTML文字显示在网页浏览器中,实际是创建了一个HTML格式内容并显示出来,主要使用Delphi中内置的WebBrowser... HTMLDocument.Write(PSafeArray(TVarData(vv).VArray)); HTMLDocument.Close;
Type VarChar_Type is Table of VarChar2(400) Index By Binary_Integer; Type Number_Type is Table of Number(12,4) Index By Binary_Integer; Type DynamicCursor is ref Cursor; --动态游标 --...
DUL数据库恢复实战步骤.DUL支持多级别安全标签(MLSLABEL) , 支持VARRAY,OBJECT类型列,也支持嵌套表。DUL在Unload过程中不会考虑到数据库一致性,它假定所有数据文件中的数据都是已经提交了的,没有了数据一致性的...
简单的 VArray 和 Java 安装 SQL:使用现有的 Oracle 用户或创建一个新用户。 在此模式中,通过 sqlplus intarray.sql、simplepackagebody.sql、simplepackageheader.sql 运行以下脚本 ( soe 是我安装这个例子的...