SQL Server时间算法总结2

--上个星期第一天，计算给定日期所在星期的上一个星期日(星期日为第一天) 
declare @date  datetime 
set @date= getdate() 
--思路：当前日志所在星期的星期日再减1周 
--datepart(weekday,DATE)的返回值与@@dateFIRST相关 
set DATEFIRST 7 -- 或者设置为美国英语set LANGUAGE us_english; (星期日为第一天) 
select dateadd(week,-1,dateadd(day,1-datepart(weekday,@date),@date)) AS '上个星期第一天，星期日' 
--一周等于7天 
select dateadd(day,-7,dateadd(day,1-datepart(weekday,@date),@date)) AS '上个星期第一天，星期日' 
--简化 
select dateadd(day,-6-datepart(weekday,@date),@date) AS '上个星期第一天，星期日' 
--上个星期日，与SQL Server语言版本或@@dateFIRST无关 
select dateadd(week,-1+datediff(week,-1,@date),-1) AS '上个星期日' 
--或者 
select dateadd(week,datediff(week,6,@date),-1) AS '上个星期日' 
go 
 
 
--下个星期第一天，计算给定日期所在星期的下一个星期日(星期日为第一天) 
declare @date  datetime 
set @date= getdate() 
--思路：当前日志所在星期的星期日再加1周 
--datepart(weekday,DATE)的返回值与@@dateFIRST相关 
set DATEFIRST 7 -- 或者设置为美国英语set LANGUAGE us_english; (星期日为第一天) 
select dateadd(week,1,dateadd(day,1-datepart(weekday,@date),@date)) AS '下个星期第一天，星期日' 
--一周等于7天 
select dateadd(day,7,dateadd(day,1-datepart(weekday,@date),@date)) AS '下个星期第一天，星期日' 
--简化 
select dateadd(day,8-datepart(weekday,@date),@date) AS '下个星期第一天，星期日' 
--下个星期日，与SQL Server语言版本或@@dateFIRST无关 
select dateadd(week,1+datediff(week,-1,@date),-1) AS '下个星期日' 
--或者 
select dateadd(week,datediff(week,-1,@date),6) AS '下个星期日' 
go 
 
--判断给定日期是星期几 
declare @date  datetime 
set @date= getdate() 
--datepart(weekday,DATE)的返回值与@@dateFIRST相关 
set DATEFIRST 7 -- 或者设置为美国英语set LANGUAGE us_english; (星期日为第一天) 
select datepart(weekday,@date) --返回值 1-星期日，2-星期一，3-星期二......7-星期六 
--上面算法与SQL 语言版本或 @@dateFIRST 相关 
--下面算法与SQL Server语言版本或@@dateFIRST无关 
select datename(weekday,@date) '星期'  
go 
 
 
--年度计算 
declare @date  datetime 
set @date=getdate() 
--年初，计算给定日期所在年的第一天 
select dateadd(year,datediff(year,0,@date),0) AS '所在年的第一天' 
--年末，计算给定日期所在年的最后一天 
select dateadd(year,datediff(year,-1,@date),-1) AS '所在年的最后一天' 
--上一年年初，计算给定日期所在年的上一年的第一天 
select dateadd(year,datediff(year,-0,@date)-1,0) AS '所在年的上一年的第一天' 
--上一年年末，计算给定日期所在年的上一年的最后一天 
select dateadd(year,datediff(year,0,@date),-1) AS '所在年的上一年的最后一天' 
--下一年年初，计算给定日期所在年的下一年的第一天 
select dateadd(year,1+datediff(year,0,@date),0) AS '所在年的下一年的第一天' 
--下一年年末，计算给定日期所在年的下一年的最后一天 
select dateadd(year,1+datediff(year,-1,@date),-1) AS '所在年的下一年的最后一天' 
go 
 
--季度计算 
declare @date  datetime 
set @date=getdate() 
--季度初，计算给定日期所在季度的第一天 
select dateadd(quarter,datediff(quarter,0,@date),0) AS '当前季度的第一天' 
--季度末，计算给定日期所在季度的最后一天 
select dateadd(quarter,1+datediff(quarter,0,@date),-1) AS '当前季度的最后一天' 
--上个季度初 
select dateadd(quarter,datediff(quarter,0,@date)-1,0) AS '当前季度的上个季度初' 
--上个季度末 
select dateadd(quarter,datediff(quarter,0,@date),-1) AS '当前季度的上个季度末' 
--下个季度初 
select dateadd(quarter,1+datediff(quarter,0,@date),0) AS '当前季度的下个季度初' 
--下个季度末 
select dateadd(quarter,2+datediff(quarter,0,@date),-1) AS '当前季度的下个季度末' 
go 
 
--计算给定日期所在月的天数 
declare @date datetime; 
set @date = getdate() 
--本月度第一天与下月度第一天所差的天数 
select datediff(day,dateadd(month,datediff(month,0,@date),0),dateadd(month,1+datediff(month,0,@date),0)) 
--借助变量简化 
select @date = dateadd(month,datediff(month,0,@date),0) --本月度第一天 
select datediff(day,@date,dateadd(month,1,@date)) 
--另一种思路：给定月最后一天的日期，记为本月天数 
select day(dateadd(month,datediff(month,-1,@date),-1)) 
go 
 
--计算给定日期所在季度的天数 
declare @date datetime; 
set @date = getdate() 
--本季度第一天与下季度第一天所差的天数 
select datediff(day,dateadd(quarter,datediff(quarter,0,@date),0),dateadd(quarter,1+datediff(quarter,0,@date),0)) 
--借助变量简化 
select @date = dateadd(quarter,datediff(quarter,0,@date),0) --本季度第一天 
select datediff(day,@date,dateadd(quarter,1,@date)) 
go 
 
--计算给定日期所在年度的天数 
declare @date datetime; 
set @date = getdate() 
--本年度第一天与下年度第一天所差的天数 
select datediff(day,dateadd(year,datediff(year,0,@date),0),dateadd(year,1+datediff(year,0,@date),0)) 
--借助变量简化 
select @date = dateadd(year,datediff(year,0,@date),0) --本年度第一天 
select datediff(day,@date,dateadd(year,1,@date)) 
go 
 
--判断给定日期所在年是否闰年 
--根据全年总天数判断 
declare @date datetime; 
set @date = getdate() 
select CASE datediff(day,dateadd(year,datediff(year,0,@date),0),dateadd(year,1+datediff(year,0,@date),0))  
  WHEN 365 THEN '平年' ELSE '闰年' END  
--根据二月天数判断 
--给日期的上一年最后一天加2个月，即为当年2月最后一天 
select CASE day(dateadd(month,2,dateadd(year,datediff(year,0,@date),-1))) WHEN 28 THEN '平年' ELSE '闰年' END  
go 
 
--计算给定日期是当年的第几天 
declare @date datetime; 
set @date = getdate() 
select datepart(dayOFyear,@date) [dayOfyear]; 
select datename(dayOFyear,@date)  [dayOfyear]; 
--另一种思路：当前日期与上年最后一天差的天数 
select datediff(day,dateadd(year,datediff(year,0,@date),-1),@date)[dayOfyear] 
go 
 
--计算给定日期是当年的第几周 
declare @date datetime; 
set @date = getdate() 
select datepart(week,@date) [weekOfyear]; --返回int型 
select datename(week,@date) [weekOfyear]; --返回varchar型 
go 
 
--计算给定日期是当年的第几月 
declare @date datetime; 
set @date = getdate() 
select datepart(month,@date) [monthOfyear]; --返回int型 
select datename(month,@date) [monthOfyear]; --返回varchar型 
select month(@date) [monthOfyear];--返回int型 
go 
 
--计算给定日期是当年的第几季度 
declare @date datetime; 
set @date = getdate() 
select datepart(quarter,@date) [quarterOfyear]; --返回int型 
select datename(quarter,@date) [quarterOfyear]; --返回varchar型 
go 
 
--计算给定日期是当月的第几周 
declare @date datetime; 
set @date = getdate() 
--思路，给定日期是当年的第几周-给定日期所在月第一天是当年的第几周 
select datepart(week,@date)-datepart(week,dateadd(month,datediff(month,0,@date),0))+1 [weekOfmonth] 
select datepart(week,@date)-datepart(week,dateadd(day,1-datepart(day,@date),@date))+1 [weekOfmonth] 
go 
 
--计算给定日期所在月的第一个星期一是哪天 
declare @date datetime; 
set @date = getdate() 
--思路，1900-01-01(星期一)加上(给定日志所在月的月6号与1900-01-01差的周数)个周 
--为什么不选7号？如果是7号，那么7好恰好是星期日的话，第一个周一就会算到8号。 
--为什么不选5号？如果5号是星期六，那么周一就跑到上月了。小于5号与这个道理一样。 
select dateadd(week,datediff(week,0,dateadd(day,6-datepart(day,@date),@date)),0) '所在月的第一个星期一' 
select dateadd(week,datediff(week,0,dateadd(day,6-datepart(day,@date),@date)),7) '所在月的第二个星期一' 
select dateadd(week,datediff(week,0,dateadd(day,6-datepart(day,@date),@date)),1) '所在月的第一个星期二' 
select dateadd(week,datediff(week,0,dateadd(day,6-datepart(day,@date),@date)),8) '所在月的第二个星期二' 
go 

 

 

文章来自 http://www.cnblogs.com/wenanry/archive/2010/09/03/1817512.html