经典批处理实现自动关机(BAT)
作者:柳永法 转自:http://www.yongfa365.com/ 点击:904 发布日期:2007-12-4
这两个自动关机命令基本上一样,不过都很精典,值得“研究”下,真的是研究,在服务器上这个很有用的,因为服务器上的权限限制很严格,用DOS的批处理真的可以做很多事,比如这里面的取时间的方法,我试了好多方法都没实现,原来也这么简单。呵呵,感觉很好
经典批处理实现自动关机1.BAT
@ECHO off
TITLE 自动关机程序 作者:廖晓青
:start
CLS
COLOR 1f
rem 使用COLOR命令对控制台输出颜色进行更改
MODE con: COLS=41 LINES=18
rem MODE语句为设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%点%tm2%分%tm3%秒
ECHO =========================================
ECHO 请选择要进行的操作,然后按回车
ECHO ───────────────
ECHO.
ECHO 1. 定时关机
ECHO 2. 倒计时关机
ECHO 3. 删除定时关机任务
ECHO 4. 查看任务状态
ECHO 5. 刷新当前时间
ECHO 6. 重新启动
ECHO 7. 锁定计算机
ECHO 8. 注销
ECHO 9. 退出
ECHO.
:cho
SET Choice=
SET /P Choice=选择:
rem 设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,IF语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效,请重新输入
ECHO.
GOTO cho
:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否设定为每天执行关机命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour
:yes
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 设定为每周的星期一至星期日,即为每天
IF NOT errorlevel 1 GOTO ok
rem 如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO yes
:no
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO no
:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start
:outtime
CLS
ECHO.
ECHO 请输入倒计时秒数
ECHO ────────
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)
SET timed=
SET /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是无效的关机时间,请重新输入
ECHO.
GOTO outtime
:delAt
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
GOTO start
:view
MODE con: COLS=85 LINES=18
COLOR 70
ECHO.
at
ECHO 按任意键继续...
PAUSE >nul
GOTO start
:restart
shutdown -r -t 0
:lock
rundll32.exe user32.dll,LockWorkStation
goto start
:logoff
logoff
:end
exit
经典批处理实现自动关机2.BAT
@echo off
title 自动关机程序 作者:青剑
rem 这里改成你的名字好了
color 17
rem 如果你不喜欢命令行默认的黑底白字模式,可以用color命令进行更改,上面"17"代表蓝底白字.
:start
echo.
echo.
echo 请选择要进行的操作,然后按回车:
echo.
echo 1. 定时关机
echo 2. 倒计时关机
echo 3. 删除定时关机任务
echo 4. 查看定时关机任务状态
echo 5. 注销
echo 6. 退出
echo.
:set
SET a=
SET /P a=选择:
rem 设定变量"a"为用户输入的字符
IF NOT '%a%'=='' SET a=%a:~0,1%
ECHO.
IF /I '%a%'=='1' goto 1
IF /I '%a%'=='2' goto 2
IF /I '%a%'=='3' goto 3
IF /I '%a%'=='4' goto 4
IF /I '%a%'=='5' goto 5
IF /I '%a%'=='6' goto 6
rem 如果输入的字符不是1-6,将返回重新输入
echo %a% 选择无效,请重新输入:
echo.
goto set
:1
echo 请输入关机时间,(如12:00:00)
set shutdowntime=
set /p shutdowntime=
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF not errorlevel 1 goto ok
rem 如果输入正确,就执行:ok后面的语句
echo %shutdowntime% 不是标准的时间格式,请重新输入
echo.
goto 1
:ok
echo.
echo 设定完毕! 按任意键继续...
pause >nul
cls
goto start
:2
echo 您想要多少秒后关机
echo (若设定后要取消,单击"确定"后按Ctrl+C键两次)
set timed=
set /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 goto ok
echo %timed% 是无效的关机时间,请重新输入
echo.
goto 2
:3
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
cls
goto start
:4
at
echo 按任意键继续...
pause >nul
cls
goto start
:5
logoff
:6
exit
分享到:
相关推荐
windows 自动关机 bat 批处理 自动关机 定时关机 每天定时关机
对于校园网用户,经常是按点断电,必须时刻考虑断电问题,该批处理文件可以让你丢掉这个烦恼,里边的时间可以自己去改,只需将bat该为txt,改完后再改回来即可。 放在系统启动项里边,就会开机自启动。
自己学批处理写的小程序,此程序可以定时关机,倒计时关机,重启,注销,等等!定时关机可以定时到任何时候,可以自定义循环时间等!原理很简单,是菜鸟写给懒菜鸟的
1、有的时候晚上电脑下载或处理东西需要一段时间自动关机。 2、给老忘记关电脑的老师准备。 希望大家用的开心!!!!1、有的时候晚上电脑下载或处理东西需要一段时间自动关机。 2、给老忘记关电脑的老师准备。1、...
对电脑可以进行直接操作的程序,是dos命令的表达方式
自动关机软件,点击输入预计的关机倒计时,然后回车键就可以了。 bat文件,批处理文件
文件包中有两个批处理文件,一是部署计划任务的批处理文件,二是执行关机的批处理文件。 一主要为执行schtasks的创建计划任务的命令,默认设置为每天晚8点执行。 二主要是执行shutdown关机和取消关机的命令。 大家...
Oracle数据库批处理关闭服务,启动也可以通过找到服务做类似文件
windows自动关机批处理文件,要啥第三方软件,安全可靠,可查可抗
清理垃圾完后关机.bat 无毒批处理 很简单,下载后自己编辑看代码即可。。
Windows电脑,自动定时+休眠+睡眠+关机 批处理文件 .bat
批处理 自动关机 支持定时 倒计时 定时任务支持daily任务和once任务 倒计时有系统倒计时,手动取消 和内置计时,可直接关闭取消 附带锁屏重启和注销,方便操作。
自动关机的bat文件 混点积分呵呵 2008年12月5日22:53:43
运行批处理,可以执行再XXX秒后关机的命令。支持XP和WIN7。
自动完成电脑系统垃圾清理后自动整理磁盘碎片,结束后自动关机哦!
Windows系统非正常关机后,开机会出现磁盘扫描,这个过程有时候非常的长,为了节省时间,我们可以用这个批处理关掉系统带的这个功能,需要做磁盘检查的时候我们再磁盘属性里设置即可。
实现定时关机的bat代码,非原创,经试验win7可以实现
当你大晚上下载迅雷的时候怕片下完了电脑没人守 很头疼 怎么办呢 自动关机 方便快捷
批处理做的自动关机脚本,未加密 主要功能: 1.定时关机 2.倒计时关机
提供2个自动关机的批处理命令,供大家参考,解压缩后右击bat文件选择编辑即可看到代码,双击即可执行